///////////////////////////////////////////////////////////////////////////
//  Copyright (C) Wizardry and Steamworks 2024 - License: GNU MIT        //
//  Please see: http://www.gnu.org/licenses/gpl.html for legal details,  //
//  rights of fair usage, the disclaimer and warranty conditions.        //
///////////////////////////////////////////////////////////////////////////
// This template is a resilient implementation of a pre-WiFi connection  //
// environment that allows the user to configure the Ssid and password   //
// for the WiFi network via a built-in web-server that is automatically  //
// started by the template when no WiFi network has been configured.     //
///////////////////////////////////////////////////////////////////////////
// Purpose ////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////
// One of the problems is that given the cost, ESP devices are bought in //
// bulk, programmed and then sprawled out allover a site but typically   //
// Arduino templates have little accountibility or resillience built-in  //
// that would make the templates resist ESP resets and still be able to  //
// connect to the WiFi network. Similarly, in case the site is mobile,   //
// and in case the WiFi network changes, then all the ESPs will just     //
// have to be reprogrammed manually by the user which is a daunting task //
// relative to the amount of ESP devices in use. This template addresses //
// that issue by creating a robust mechanism where the ESP device will   //
// reboot in a preboot AP mode in case the WiFi network cannot be found  //
// or connected to in order to allow the user to reconfigure the ESP.    //
///////////////////////////////////////////////////////////////////////////
// Example Usage //////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////
//   * configure the template parameters as need be within the           //
//     "configurable parameters" section of this template, the password  //
//     defined as a "master password" will grant access to configurng    //
//     the template and will also be used as the OTA password            //
//   * add any user-code to the connectedLoop() function that will be    //
//     called by the Arduino loop with a delay of 1 millisecond (the     //
//     user must include a delay in order to not throttle the CPU)       //
//   * when booting, the template will generate an Ssid based on the ESP //
//     CPU identifier consisting of up to two digits and will blink the  //
//     built-in ESP LED in sequence in order to give away the AP         //
//   * connect to the numeric AP started by the ESP and configure the    //
//     network Ssid and password                                         //
//   * the template will now connect to the WiFi network using the       //
//     provided Ssid and password; iff. the WiFi disconnects from the    //
//     WiFi network for more than the amount of milliseconds given by:   //
//                                                                       //
//     WIFI_RETRY_TIMEOUT * WIFI_CONNECT_TRIES                           //
//                                                                       //
//     then the template will restart again in AP mode, blink the LED    //
//     of the numeric Ssid and wait to be configured for a WiFi network  //
///////////////////////////////////////////////////////////////////////////
// Libraries //////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////
// The libraries used are minimal and the kind of libraries that have a  //
// wide-range of applications, in particular if the ESP device is WiFi   //
// enabled. Here is a complete list of libraries used by the template:   //
//   * ArduinoJson (very popular JSON library)                           //
//   * TickTwo (timer library for asynchronous processing)               //
///////////////////////////////////////////////////////////////////////////
// Credits ////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////
// The template is loosely inspired by the many captive portal solutions //
// out there but with some minimalism in mind and additionally exposing  //
// various configurable parameters such as the HTML webpage. Other close //
// similarities consist in the Tasmota firmware that accomplishes more   //
// or less the same switch between connected to a WiFi network and AP    //
// mode that allows the user to configure the WiFi network.              //
///////////////////////////////////////////////////////////////////////////

///////////////////////////////////////////////////////////////////////////
//  configurable parameters                                              //
///////////////////////////////////////////////////////////////////////////

// comment out to enable debugging
#define DEBUG 1

// set the master password for OTA updates and access to the soft AP
#define PREBOOT_MASTER_PASSWORD ""

// the name and length of the cookie to use for authentication
#define PREBOOT_COOKIE_NAME "ArduinoPrebootCookie"
#define PREBOOT_COOKIE_MAX_LENGTH 256

// timeout to establish STA connection in milliseconds
#define WIFI_RETRY_TIMEOUT 1000 * 10

// retries as multiples of WIFI_RETRY_TIMEOUT milliseconds
#define WIFI_CONNECT_TRIES 60

// how much time to wait for a client to reconfigure before switching to client mode again
#define WIFI_SERVER_TIMEOUT 1000 * 60 * 3

// the time between blinking a single digit
#define BLINK_DIT_LENGTH 250

// the time between blinking the whole number
#define BLINK_DAH_LENGTH 2500

// watchdog timeout till the hardware is considered locked up
#define WATCHDOG_TIMEOUT 15000

// The MQTT broker to connect to.
#define MQTT_HOST "iot.internal"
// The MQTT broker username.
#define MQTT_USERNAME ""
// The MQTT broker password.
#define MQTT_PASSWORD ""
// The MQTT broker port.
#define MQTT_PORT 1883
// The MQTT topic
#define MQTT_TOPIC ""
#define MQTT_TOPIC_OUTBOX "messages"

// Platform specific defines.
#if defined(ARDUINO_ARCH_ESP8266)
#define GET_CHIP_ID() (ESP.getChipId())
#elif defined(ARDUINO_ARCH_ESP32)
#define GET_CHIP_ID() ((uint16_t)(ESP.getEfuseMac() >> 32))
#endif

// The hostname to use.
#define HOSTNAME() String("gauge") //String("esp-" + String(GET_CHIP_ID(), HEX))
#define CONFIGURATION_FILE_NAME "/config.json"
#define CONFIGURATION_MAX_LENGTH 1024

///////////////////////////////////////////////////////////////////////////
//  includes                                                             //
///////////////////////////////////////////////////////////////////////////
#include <DNSServer.h>
#if defined(ARDUINO_ARCH_ESP32)
#include <WiFi.h>
#include "esp_mac.h"
#include <WebServer.h>
#include <ESPmDNS.h>
#elif defined(ESP8266)
#include <ESP8266WiFi.h>
#include <ESP8266mDNS.h>
#include <ESP8266WebServer.h>
#endif

// set up watchdog
#if defined(ESP32)
#include <esp_task_wdt.h>
#if defined(ESP_ARDUINO_VERSION_MAJOR) && ESP_ARDUINO_VERSION_MAJOR >= 3
// For ESP32 Arduino Core v3.0.0+
esp_task_wdt_config_t twdt_config = {
  .timeout_ms = WATCHDOG_TIMEOUT * 1000,
  .idle_core_mask = (1 << portNUM_PROCESSORS) - 1, // Monitor all cores
  .trigger_panic = true
};
#endif
#endif

#include <FS.h>
#include <LittleFS.h>
#include <ArduinoJson.h>
// Arduino OTA
#include <WiFiUdp.h>
#include <ArduinoOTA.h>
#include <TickTwo.h>

// MQTT
#include <PubSubClient.h>
// Maximal size of an MQTT payload
#define MQTT_PAYLOAD_MAX_LENGTH MQTT_MAX_PACKET_SIZE
#include <StreamUtils.h>

// Gauge application
#include <DigiPotX9Cxxx.h>

///////////////////////////////////////////////////////////////////////////
//  function definitions                                                 //
///////////////////////////////////////////////////////////////////////////
byte* getHardwareAddress(void);
char* getHardwareAddress(char colon);
String generateTemporarySSID(void);
void arduinoOtaTickCallback(void);
void blinkDigitsDahTickCallback(void);
void blinkDigitsDitTickCallback(void);
void blinkDigitsBlinkTickCallback(void);
void clientWifiTickCallback(void);
void serverWifiTickCallback(void);
void handleServerWifi(void);
void handleClientWifi(void);

bool setConfiguration(const char* configurationFile, JsonDocument& configuration);
int getConfiguration(const char* configurationFile, JsonDocument& configuration);

void handleRootHttpRequest(void);
void handleRootCssRequest(void);
void handleSetupHttpRequest(void);
void handleRootHttpGet(void);
void handleSetupHttpGet(void);
void handleRootHttpPost(void);
void handleSetupHttpPost(void);
void handleHttpNotFound(void);

void rebootTickCallback(void);

// MQTT
void mqttTickCallback(void);
String getMqttTopic(void);
String getMqttClientId(void);
bool mqttConnect(void);
void mqttCallback(char *topic, byte *payload, unsigned int length);
constexpr unsigned int mqttGpioActionHash(const char *s, int off = 0);

///////////////////////////////////////////////////////////////////////////
//  variable declarations                                                //
///////////////////////////////////////////////////////////////////////////
IPAddress softAPAddress(8, 8, 8, 8);
IPAddress softAPNetmask(255, 255, 255, 0);

DNSServer dnsServer;
#if defined(ARDUINO_ARCH_ESP8266)
ESP8266WebServer server(80);
#elif defined(ARDUINO_ARCH_ESP32)
WebServer server(80);
#endif

TickTwo arduinoOtaTick(arduinoOtaTickCallback, 1000);
TickTwo rebootTick(rebootTickCallback, 1000);
TickTwo clientWifiTick(clientWifiTickCallback, 25);
TickTwo serverWifiTick(serverWifiTickCallback, 250);
TickTwo blinkDigitsDahTick(blinkDigitsDahTickCallback, BLINK_DAH_LENGTH);
TickTwo blinkDigitsDitTick(blinkDigitsDitTickCallback, BLINK_DIT_LENGTH);
TickTwo blinkDigitsBlinkTick(blinkDigitsBlinkTickCallback, 25);

enum bootMode : int {
  BOOT_MODE_NONE = 0,
  BOOT_MODE_CLIENT,
  BOOT_MODE_SERVER
};

char* authenticationCookie = NULL;
bool otaStarted;
bool otaInProgress;
bool networkConnected;
int clientConnectionTries;
bool rebootPending;
int temporarySSIDLength;
int temporarySSIDIndex;
int* temporarySSIDNumbers;
int blinkLedState;
bool discoveryStarted;
WiFiEventHandler wifiDisconnectHandler;

// MQTT
String mqttTopicCache;
String mqttClientIdCache;
WiFiClient espClient;
PubSubClient mqttClient(espClient);
TickTwo mqttTick(mqttTickCallback, 250);

// Gauge application
// pins in sequence: INC, U/D, CS
#if defined(ARDUINO_ARCH_ESP8266)
DigiPot microphonePotentiometer(D3, D2, D4);
#elif defined(ARDUINO_ARCH_ESP32)
DigiPot microphonePotentiometer(12, 8, 3);
#endif

///////////////////////////////////////////////////////////////////////////
//  HTML & CSS templates                                                 //
///////////////////////////////////////////////////////////////////////////
const char *GENERIC_CSS_TEMPLATE PROGMEM = R"html(
* {
  box-sizing: border-box;
}
body {
  background-color: #3498db;
  font-family: "Arial", sans-serif;
  padding: 50px;
}
.container {
  margin: 20px auto;
  padding: 10px;
  width: 300px;
  height: 100%;
  background-color: #fff;
  border-radius: 5px;
  margin-left: auto;
  margin-right: auto;
}
h1 {
  width: 70%;
  color: #777;
  font-size: 32px;
  margin: 28px auto;
  text-align: center;
}
form {
  text-align: center;
}
input {
  padding: 12px 0;
  margin-bottom: 10px;
  border-radius: 3px;
  border: 2px solid transparent;
  text-align: center;
  width: 90%;
  font-size: 16px;
  transition: border 0.2s, background-color 0.2s;
}
form .field {
  background-color: #ecf0f1;
}
form .field:focus {
  border: 2px solid #3498db;
}
form .btn {
  background-color: #3498db;
  color: #fff;
  line-height: 25px;
  cursor: pointer;
}
form .btn:hover,
form .btn:active {
  background-color: #1f78b4;
  border: 2px solid #1f78b4;
}
.pass-link {
  text-align: center;
}
.pass-link a:link,
.pass-link a:visited {
  font-size: 12px;
  color: #777;
}
table {
  border: 1px solid #dededf;
  border-collapse: collapse;
  border-spacing: 1px;
  margin-left: auto;
  margin-right: auto;
  width: 80%;
}
td {
  border: 1px solid #dededf;
  background-color: #ffffff;
  color: #000000;
  padding: 1em;
}
)html";

const char *HTML_SETUP_TEMPLATE PROGMEM = R"html(
<!DOCTYPE html>
<html lang="en">
  <head>
    <title>setup</title>
    <link rel="stylesheet" href="/style.css">
  </head>
  <body>
    <div class="container">
      <h1>setup</h1>
      <table>
        <tr>
          <td>AP</td>
          <td>%AP%</td>
        </tr>
        <tr>
          <td>MAC</td>
          <td>%MAC%</td>
        </tr>
      </table>
      <br>
      <form method="POST" action="/setup">
        <label for="name">Name</label>
        <input id="name" type="text" name="name" value="%NAME%" class="field">
        <label for="ssid">SSID</label>
        <input id="ssid" type="text" name="ssid" class="field">
        <label for="password">Password</label>
        <input id="password" type="password" name="password" class="field">
        <hr>
        <label for="mqttClientId">MQTT Client ID</label>
        <input id="mqttClientId" type="text" name="mqttClientId" value="%MQTT_CLIENT_ID%" class="field">
        <label for="mqttHost">MQTT Host</label>
        <input id="mqttHost" type="text" name="mqttHost" value="%MQTT_HOST%" class="field">
        <label for="mqttPort">MQTT Port</label>
        <input id="mqttPort" type="number" min="1" max="65535" name="mqttPort" value="%MQTT_PORT%" class="field">
        <label for="mqttTopic">MQTT Topic</label>
        <input id="mqttTopic" type="text" name="mqttTopic" value="%MQTT_TOPIC%" class="field">
        <label for="mqttUsername">MQTT Username</label>
        <input id="mqttUsername" type="text" name="mqttUsername" value="%MQTT_USERNAME%" class="field">
        <label for="mqttPassword">MQTT Password</label>
        <input id="mqttPassword" type="password" name="mqttPassword" value="%MQTT_PASSWORD%" class="field">
        <input type="submit" value="login" class="btn">
      </form>
    </div>
  </body>
</html>
)html";

const char *HTML_AUTH_TEMPLATE PROGMEM = R"html(
<!DOCTYPE html>
<html lang="en">
  <head>
    <title>Preboot Access</title>
    <link rel="stylesheet" href="/style.css">
  </head>
  <body>
    <div class="container">
      <h1>admin</h1>
      <form method="POST">
        <input id="password" type="password" name="password" class="field" placeholder="password">
        <input type="submit" value="login" class="btn">
      </form>
    </div>
  </body>
</html>
)html";

///////////////////////////////////////////////////////////////////////////
//  begin Arduino                                                        //
///////////////////////////////////////////////////////////////////////////
void setup() {
#ifdef DEBUG
  Serial.begin(115200);
  // wait for serial
  while (!Serial) {
    delay(100);
  }

  Serial.println();
#else
  Serial.end();
#endif

#ifdef DEBUG
  Serial.println("Mounting filesystem...");
#endif
#if defined(ARDUINO_ARCH_ESP8266)
  if (!LittleFS.begin()) {
#ifdef DEBUG
    Serial.println("LittleFS mount failed, formatting and rebooting...");
#endif
    LittleFS.format();
    delay(1000);
    ESP.restart();
#elif defined(ARDUINO_ARCH_ESP32)
  if (!LittleFS.begin(true)) {
#endif
#ifdef DEBUG
    Serial.println("LittleFS mount & format failed...");
#endif
    return;
  }

#ifdef DEBUG
  Serial.printf("Checking if WiFi server must be started...\n");
#endif
  // check if ssid is set and start soft AP or STA mode
  JsonDocument configuration;
  if(getConfiguration(CONFIGURATION_FILE_NAME, configuration) == -1) {
#ifdef DEBUG
    Serial.println("Unable to retrieve configuration.");
#endif
    delay(60000);
    ESP.restart();
    return;
  }

  switch(configuration["boot"].as<int>()) {
    case BOOT_MODE_CLIENT:
#ifdef DEBUG
      Serial.printf("Client connecting to WiFi...\n");
#endif

      // register common error handler for client disconnects
#ifdef ESP32
      // ESP32 uses a simple global event system
      WiFi.onEvent(clientWifiDisconnectCallback);
#elif defined(ESP8266)
      // ESP8266 requires assigning the handler to our global variable
      wifiDisconnectHandler = WiFi.onStationModeDisconnected(clientWifiDisconnectCallback);
      #endif
      clientWifiTick.start();
      break;
    case BOOT_MODE_SERVER:
    case BOOT_MODE_NONE:
#ifdef DEBUG
      Serial.printf("Server AP starting...\n");
#endif
      // start soft AP
      rebootTick.start();
      serverWifiTick.start();
      break;
  }

  // setup OTA
  ArduinoOTA.setHostname(configuration["name"].as<const char*>());
  // allow flashing with the master password
  ArduinoOTA.setPassword(PREBOOT_MASTER_PASSWORD);
  ArduinoOTA.onStart([]() {
    // mark OTA as started
    otaInProgress = true;

    // stop LittleFS as per the documentation
    LittleFS.end();
    
    String type;
    if (ArduinoOTA.getCommand() == U_FLASH) {
      type = "sketch";
    } else {  // U_FS
      type = "filesystem";
    }

    // NOTE: if updating FS this would be the place to unmount FS using FS.end()
#ifdef DEBUG
    Serial.println("Start updating " + type);
#endif
  });
  ArduinoOTA.onEnd([]() {
    otaInProgress = false;
#ifdef DEBUG
    Serial.println("\nEnd");
#endif
    // restart the device
#ifdef DEBUG
    Serial.printf("Restarting ESP.\n");
#endif
    delay(1000);
    ESP.restart();
  });
  ArduinoOTA.onProgress([](unsigned int progress, unsigned int total) {
#ifdef DEBUG
    Serial.printf("Progress: %u%%\r", (progress / (total / 100)));
#endif
  });
  ArduinoOTA.onError([](ota_error_t error) {
#ifdef DEBUG
    Serial.printf("Error[%u]: ", error);
#endif
    if (error == OTA_AUTH_ERROR) {
#ifdef DEBUG
      Serial.println("Auth Failed");
#endif
    } else if (error == OTA_BEGIN_ERROR) {
#ifdef DEBUG
      Serial.println("Begin Failed");
#endif
    } else if (error == OTA_CONNECT_ERROR) {
#ifdef DEBUG
      Serial.println("Connect Failed");
#endif
    } else if (error == OTA_RECEIVE_ERROR) {
#ifdef DEBUG
      Serial.println("Receive Failed");
#endif
    } else if (error == OTA_END_ERROR) {
#ifdef DEBUG
      Serial.println("End Failed");
#endif
    }
  });

  #if defined(ESP8266)
    // ESP8266: wdtEnable(timeout_ms) - Note: timeout_ms is currently ignored 
    // by the ESP8266 core; it uses a default of ~1.5s to 3.2s.
    ESP.wdtEnable(WATCHDOG_TIMEOUT * 1000); 
    Serial.println("ESP8266 Watchdog Enabled.");

  #elif defined(ESP32)
    #if defined(ESP_ARDUINO_VERSION_MAJOR) && ESP_ARDUINO_VERSION_MAJOR >= 3
      // ESP32 Core v3.x+
      esp_task_wdt_init(&twdt_config);
    #else
      // ESP32 Core v2.x and older
      esp_task_wdt_init(WATCHDOG_TIMEOUT, true);
    #endif
    esp_task_wdt_add(NULL); // Subscribe the current main task to WDT
    Serial.println("ESP32 Watchdog Enabled.");
  #endif

  // start timers / threads
  arduinoOtaTick.start();
  rebootTick.start();

  mqttTick.start();
}

void loop() {
  // Feed the "dog" regularly to prevent reset
  #if defined(ESP8266)
    ESP.wdtFeed();
  #elif defined(ESP32)
    esp_task_wdt_reset();
  #endif

  arduinoOtaTick.update();
  rebootTick.update();
  clientWifiTick.update();
  serverWifiTick.update();
  blinkDigitsDitTick.update();
  blinkDigitsDahTick.update();
  blinkDigitsBlinkTick.update();
  
  // scanner application
  mqttTick.update();
}

///////////////////////////////////////////////////////////////////////////
//  end Arduino                                                          //
///////////////////////////////////////////////////////////////////////////

///////////////////////////////////////////////////////////////////////////
//  MQTT                                                            //
///////////////////////////////////////////////////////////////////////////
constexpr unsigned int mqttGpioActionHash(const char *s, int off) {                        
    return !s[off] ? 5381 : (mqttGpioActionHash(s, off+1)*33) ^ s[off];                           
}

String getMqttTopic(void) {
  if(mqttTopicCache.length() != 0) {
    return mqttTopicCache;
  }

  mqttTopicCache = String(HOSTNAME());
  JsonDocument configuration;
  if(getConfiguration(CONFIGURATION_FILE_NAME, configuration) == -1) {
#ifdef DEBUG
    Serial.println("Unable to retrieve configuration.");
#endif
    return mqttTopicCache;
  }

  if(!configuration["mqttTopic"].is<String>()) {
    return mqttTopicCache;
  }

  mqttTopicCache = configuration["mqttTopic"].as<String>();

  return mqttTopicCache;
}

String getMqttClientId(void) {
  // store the MQTT id in a global varible to prevent redundant CPU usage
  if(mqttClientIdCache.length() != 0) {
    return mqttClientIdCache;
  }

  mqttClientIdCache = String(HOSTNAME());
  JsonDocument configuration;
  if(getConfiguration(CONFIGURATION_FILE_NAME, configuration) == -1) {
#ifdef DEBUG
    Serial.println("Unable to retrieve configuration.");
#endif
    return mqttClientIdCache;
  }

  if(!configuration["mqttClientId"].is<String>()) {
    return mqttClientIdCache;
  }

  mqttClientIdCache = configuration["mqttClientId"].as<String>();

  return mqttClientIdCache;
}

void mqttCallback(char *topic, byte *payload, unsigned int length) {
  String msgTopic = String(topic);
  // do not listen on topics not subscribed to or on empty topics
  if(msgTopic.length() == 0) {
    return;
  }

  // only listen on the topic that has been subscribed to
  if(!msgTopic.equals(mqttTopicCache)) {
    return;
  }

  // Parse the payload sent to the MQTT topic as a JSON document.
#ifdef DEBUG
  Serial.println("Deserializing message...");
#endif
  DynamicJsonDocument doc(MQTT_PAYLOAD_MAX_LENGTH);
  DeserializationError error = deserializeJson(doc, payload, length);
  if (error) {
#ifdef DEBUG
    Serial.println("Failed to parse MQTT payload as JSON: " + String(error.c_str()));
#endif
    return;
  }

#ifdef DEBUG
  //Serial.printf("Message received on topic %s with payload %s...\n", topic, payload);
#endif

  // Do not process messages without an action key.
  if (!doc.containsKey("action")) {
#ifdef DEBUG
    Serial.printf("No action provided.\n");
#endif
    return;
  }

  String action = String(doc["action"].as<const char*>());
  // normalize action
  action.trim();
  action.toUpperCase();
  if(action.length() == 0) {
#ifdef DEBUG
    Serial.println("Empty action provided.");
#endif
    return;
  }

  DynamicJsonDocument msg(MQTT_PAYLOAD_MAX_LENGTH);
  msg["execute"] = doc;
  switch(mqttGpioActionHash(action.c_str())) {
    case mqttGpioActionHash("SOME_ACTION"):
      break;
  }

  char buff[MQTT_PAYLOAD_MAX_LENGTH];
  size_t payloadLength = serializeJson(msg, buff);
  mqttClient.publish((getMqttTopic() + "/" + MQTT_TOPIC_OUTBOX).c_str(), buff, payloadLength);
}

bool mqttConnect(void) {
  if(rebootPending) {
#ifdef DEBUG
    Serial.println("Reboot pending, cancelling MQTT connection.");
#endif
    return false;
  }
  
  // retrieve the configuration so we do not end up overwriting the old client settings
  JsonDocument configuration;
  if(getConfiguration(CONFIGURATION_FILE_NAME, configuration) == -1) {
     // if the configuration could not be retrieved then just reboot
#ifdef DEBUG
      Serial.println("Unable to retrieve configuration.");
#endif
      return false;
  }
  
#ifdef DEBUG
  Serial.printf("MQTT broker parameters, client ID %s, host %s, port %d, username %s, password %s and topic %s.\n",
    getMqttClientId().c_str(),
    configuration["mqttHost"].as<const char*>(), 
    configuration["mqttPort"].as<int>(), 
    configuration["mqttUsername"].as<const char*>(), 
    configuration["mqttPassword"].as<const char*>(),
    configuration["mqttTopic"].as<const char*>()
  );
#endif

  mqttClient.setServer(configuration["mqttHost"].as<const char*>(), configuration["mqttPort"].as<int>());
  if (mqttClient.connect(
    getMqttClientId().c_str(), 
    configuration["mqttUsername"].as<const char*>(), 
    configuration["mqttPassword"].as<const char*>())) {
    mqttClient.setCallback(mqttCallback);
#ifdef DEBUG
    Serial.print("Subscribing to MQTT topic " + getMqttTopic() + ": ");
#endif
    if (!mqttClient.subscribe(getMqttTopic().c_str())) {
#ifdef DEBUG
      Serial.println("fail");
#endif
      return false;
    }
    
#ifdef DEBUG
    Serial.println("success");
#endif

    // Announce success at connecting and subscribing to MQTT broker.
    JsonDocument doc;
    doc["client"] = getMqttClientId().c_str();
    doc["topic"] = getMqttTopic().c_str();
    doc["command"] = "hello";
    
    mqttClient.beginPublish((getMqttTopic() + "/" + MQTT_TOPIC_OUTBOX).c_str(), measureJson(doc), false);
    BufferingPrint bufferedClient(mqttClient, 64);
    serializeJson(doc, bufferedClient);
    bufferedClient.flush();
    mqttClient.endPublish();
    
    return true;
  }
  
#ifdef DEBUG
  Serial.println("Connection to MQTT broker failed with MQTT client state: " + String(mqttClient.state()));
#endif
  return false;
}

///////////////////////////////////////////////////////////////////////////
//  Arduino Loop                                                         //
///////////////////////////////////////////////////////////////////////////
void mqttTickCallback(void) {
  if(!networkConnected) {
    return;
  }
  
  // Process MQTT client loop.
  if (mqttClient.connected()) {
    mqttClient.loop();
    return;
  }
  
  if (!mqttConnect()) {
#ifdef DEBUG
    Serial.printf("Unable to connect to MQTT\n");
#endif
  }
}

///////////////////////////////////////////////////////////////////////////
//  OTA updates                                                          //
///////////////////////////////////////////////////////////////////////////
void arduinoOtaTickCallback(void) {
  ArduinoOTA.handle();
  
  if(!networkConnected) {
    return;
  }
  
  if(!otaStarted) {
    ArduinoOTA.begin();
    otaStarted = true;
  }
}

///////////////////////////////////////////////////////////////////////////
//  system-wide reboot                                                   //
///////////////////////////////////////////////////////////////////////////
void rebootTickCallback(void) {
  // if not reboot hasbeen scheduled then just return
  if(!rebootPending) {
    return;
  }
  
#ifdef DEBUG
  Serial.printf("Stopping filesystem...\n");
#endif
#ifdef DEBUG
  LittleFS.end();
#endif
#ifdef DEBUG
  Serial.printf("Rebooting...\n");
#endif
  ESP.restart();
}

///////////////////////////////////////////////////////////////////////////
//  HTTP route handling                                                  //
///////////////////////////////////////////////////////////////////////////
void handleRootHttpPost(void) {
  String password;
  for(int i = 0; i < server.args(); ++i) {
    if(server.argName(i) == "password") {
      password = server.arg(i);
      continue;
    }
  }

  if(!password.equals(PREBOOT_MASTER_PASSWORD)) {
    server.sendHeader("Location", "/");
    server.sendHeader("Cache-Control", "no-cache");
    server.send(302);
    return;
  }

#ifdef DEBUG
  Serial.println("Authentication succeeded, setting cookie and redirecting.");
#endif

  // clear old authentication cookie
  if(authenticationCookie != NULL) {
    free(authenticationCookie);
    authenticationCookie = NULL;
  }
  
  authenticationCookie = randomStringHex(8);
  char* buff = (char*) malloc(PREBOOT_COOKIE_MAX_LENGTH * sizeof(char));
  snprintf(buff, PREBOOT_COOKIE_MAX_LENGTH, "%s=%s; Max-Age=600; SameSite=Strict", PREBOOT_COOKIE_NAME, authenticationCookie);
#ifdef DEBUG
  Serial.printf("Preboot cookie set to: %s\n", buff);
#endif
  server.sendHeader("Set-Cookie", buff);
  server.sendHeader("Location", "/setup");
  server.sendHeader("Cache-Control", "no-cache");
  server.send(302);
  free(buff);
}

void handleSetupHttpPost(void) {
  String espName, ssid, password, mqttHost, mqttTopic, mqttUsername, mqttPassword, mqttClientId;
  int mqttPort;
  for(int i = 0; i < server.args(); ++i) {
    if(server.argName(i) == "name") {
      espName = server.arg(i);
      continue;
    }
    
    if(server.argName(i) == "ssid") {
      ssid = server.arg(i);
      continue;
    }

    if(server.argName(i) == "password") {
      password = server.arg(i);
      continue;
    }

    if(server.argName(i) == "mqttClientId") {
      mqttClientId = server.arg(i);
      continue;
    }

    if(server.argName(i) == "mqttHost") {
      mqttHost = server.arg(i);
      continue;
    }

    if(server.argName(i) == "mqttPort") {
      String mqttUserPort = server.arg(i);
      mqttPort = mqttUserPort.toInt();
      continue;
    }

    if(server.argName(i) == "mqttTopic") {
      mqttTopic = server.arg(i);
      continue;
    }
    
    if(server.argName(i) == "mqttUsername") {
      mqttUsername = server.arg(i);
      continue;
    }

    if(server.argName(i) == "mqttPassword") {
      mqttPassword = server.arg(i);
      continue;
    }
  }

  if(!espName || espName.length() == 0 || 
     !ssid || ssid.length() == 0 || 
     !password || password.length() == 0) {
      server.sendHeader("Location", "/");
      server.sendHeader("Cache-Control", "no-cache");
      server.send(302);
      return;
  }
  
#ifdef DEBUG
  Serial.printf("SSID %s and password %s received from web application.\n", ssid, password);
#endif
  JsonDocument configuration;
  // Miscellaneous
  configuration["boot"] = BOOT_MODE_CLIENT;
  
  // WiFi settings
  configuration["name"] = espName;
  configuration["ssid"] = ssid;
  configuration["password"] = password;
  
  // MQTT settings
  configuration["mqttClientId"] = mqttClientId;
  configuration["mqttHost"] = mqttHost;
  configuration["mqttPort"] = mqttPort;
  configuration["mqttTopic"] = mqttTopic;
  configuration["mqttUsername"] = mqttUsername;
  configuration["mqttPassword"] = mqttPassword;
  if(!setConfiguration(CONFIGURATION_FILE_NAME, configuration)) {
#ifdef DEBUG
    Serial.printf("Failed to write configuration.\n");
#endif
    server.sendHeader("Location", "/setup");
    server.sendHeader("Cache-Control", "no-cache");
    server.send(307);
    return;
  }

  server.send(200, "text/plain", "Parameters applied. Scheduling reboot...");
  
#ifdef DEBUG
  Serial.printf("Configuration applied...\n");
#endif

  rebootPending = true;
}

void handleRootHttpGet(void) {  
  // send login form
#ifdef DEBUG
  Serial.printf("Sending authentication webpage.\n");
#endif
  String processTemplate = String(HTML_AUTH_TEMPLATE);
  server.send(200, "text/html", processTemplate);
}

void handleSetupHttpGet(void) {  
  JsonDocument configuration;
  if(getConfiguration(CONFIGURATION_FILE_NAME, configuration) == -1) {
#ifdef DEBUG
    Serial.println("Unable to retrieve configuration.");
#endif
    server.sendHeader("Location", "/setup");
    server.sendHeader("Cache-Control", "no-cache");
    server.send(307);
  }
      
  String espName = HOSTNAME();
  if(configuration["name"].is<String>()) {
    espName = configuration["name"].as<String>();
  }

  String mqttHost = MQTT_HOST;
  if(configuration["mqttHost"].is<String>()) {
    mqttHost = configuration["mqttHost"].as<String>();
  }

  int mqttPort = MQTT_PORT;
  if(configuration["mqttPort"].is<String>()) {
    mqttPort = configuration["mqttPort"].as<int>();
  }
  
  String mqttTopic = getMqttTopic();
  if(configuration["mqttTopic"].is<String>()) {
    mqttTopic = configuration["mqttTopic"].as<String>();
  }

  String mqttClientId = getMqttClientId();
  if(configuration["mqttClientId"].is<String>()) {
    mqttClientId = configuration["mqttClientId"].as<String>();
  }
  
  String mqttUsername = MQTT_USERNAME;
  if(configuration["mqttUsername"].is<String>()) {
    mqttUsername = configuration["mqttUsername"].as<String>();
  }

  String mqttPassword = MQTT_PASSWORD;
  if(configuration["mqttPassword"].is<String>()) {
    mqttPassword = configuration["mqttPassword"].as<String>();
  }
  
  // send default boot webpage
#ifdef DEBUG
  Serial.printf("Sending configuration form webpage.\n");
#endif
  String processTemplate = FPSTR(HTML_SETUP_TEMPLATE);
  processTemplate.replace("%AP%", generateTemporarySSID());
  processTemplate.replace("%MAC%", getHardwareAddress(':'));
  processTemplate.replace("%NAME%", espName);
  processTemplate.replace("%MQTT_CLIENT_ID%", mqttClientId);
  processTemplate.replace("%MQTT_HOST%", mqttHost);
  processTemplate.replace("%MQTT_PORT%", String(mqttPort));
  processTemplate.replace("%MQTT_TOPIC%", mqttTopic);
  processTemplate.replace("%MQTT_USERNAME%", mqttUsername);
  processTemplate.replace("%MQTT_PASSWORD%", mqttPassword);
  server.send(200, "text/html", processTemplate);
}

void handleRootHttpRequest(void) {
  switch(server.method()) {
    case HTTP_GET:
      handleRootHttpGet();
      break;
    case HTTP_POST:
      handleRootHttpPost();
      break;
  }
}

void handleRootCssRequest(void) {
  if(server.method() != HTTP_GET) {
    handleHttpNotFound();
    return;
  }
  
#ifdef DEBUG
  Serial.println("Sending stylesheet...");
#endif  
  String rootCss = FPSTR(GENERIC_CSS_TEMPLATE);
  server.send(200, "text/css", rootCss);
}

void handleSetupHttpRequest(void) {
#ifdef DEBUG
  Serial.println("HTTP setup request received.");
#endif
  if(!server.hasHeader("Cookie")) {
#ifdef DEBUG
    Serial.println("No cookie header found.");
#endif
    server.sendHeader("Location", "/");
    server.sendHeader("Cache-Control", "no-cache");
    server.send(302);
    return;
  }
  
  String cookie = server.header("Cookie");
  if(authenticationCookie == NULL || cookie.indexOf(authenticationCookie) == -1) {
#ifdef DEBUG
    Serial.println("Authentication failed.");
#endif
    server.sendHeader("Location", "/");
    server.sendHeader("Cache-Control", "no-cache");
    server.send(302);
    return;
  }
  
  switch(server.method()) {
    case HTTP_GET:
#ifdef DEBUG
      Serial.printf("HTTP GET request received for setup.\n");
#endif
      handleSetupHttpGet();
      break;
    case HTTP_POST:
#ifdef DEBUG
      Serial.printf("HTTP POST request received for setup.\n");
#endif
      handleSetupHttpPost();
      break;
  }
}

void handleHttpNotFound(void) {
  server.sendHeader("Cache-Control", "no-cache");
  server.send(404);
}

///////////////////////////////////////////////////////////////////////////
//  set the current configuration                                        //
///////////////////////////////////////////////////////////////////////////
bool setConfiguration(const char* configurationFile, JsonDocument &configuration) {
#if defined(ARDUINO_ARCH_ESP8266)
  File file = LittleFS.open(configurationFile, "w");
#elif defined(ARDUINO_ARCH_ESP32)
  File file = LittleFS.open(configurationFile, FILE_WRITE);
#endif
  if(!file) {
#ifdef DEBUG
    Serial.println("Failed to open file for writing.");
#endif
    return false;
  }
  size_t bytesWritten = serializeJson(configuration, file);
  file.close();
#ifdef DEBUG
  Serial.printf("Written bytes %d vs. document bytes %d\n", bytesWritten, measureJson(configuration));
#endif
  return bytesWritten == measureJson(configuration);
}

///////////////////////////////////////////////////////////////////////////
//  get the current configuration                                        //
///////////////////////////////////////////////////////////////////////////
int getConfiguration(const char* configurationFile, JsonDocument &configuration) {
#if defined(ARDUINO_ARCH_ESP8266)
  File file = LittleFS.open(configurationFile, "r");
#elif defined(ARDUINO_ARCH_ESP32)
  File file = LittleFS.open(configurationFile);
#endif

  if (!file) {
#ifdef DEBUG
    Serial.println("Failed to open file for reading.");
#endif
    return false;
  }

  DeserializationError error = deserializeJson(configuration, file);
  file.close();
  
  if(error) {
#ifdef DEBUG
    Serial.printf("Deserialization failed with error %s\n", error.c_str());
#endif
    return -1;
  }

  return measureJson(configuration);
}

///////////////////////////////////////////////////////////////////////////
//  generate random string                                               //
///////////////////////////////////////////////////////////////////////////
char* randomStringHex(int length) {
  const char alphabet[] = "0123456789abcdef";
  char* payload = (char*) malloc(length * sizeof(char));
  int i;
  for (i=0; i<length; ++i) {
    payload[i] = alphabet[random(16)];
  }
  payload[i] = '\0';
  return payload;
}

///////////////////////////////////////////////////////////////////////////
//  get wireless status                                                  //
///////////////////////////////////////////////////////////////////////////
const char* wl_status_to_string(wl_status_t status) {
  switch (status) {
    case WL_NO_SHIELD: return "WL_NO_SHIELD";
    case WL_IDLE_STATUS: return "WL_IDLE_STATUS";
    case WL_NO_SSID_AVAIL: return "WL_NO_SSID_AVAIL";
    case WL_SCAN_COMPLETED: return "WL_SCAN_COMPLETED";
    case WL_CONNECTED: return "WL_CONNECTED";
    case WL_CONNECT_FAILED: return "WL_CONNECT_FAILED";
    case WL_CONNECTION_LOST: return "WL_CONNECTION_LOST";
    case WL_DISCONNECTED: return "WL_DISCONNECTED";
#if defined(ARDUINO_ARCH_ESP32)
    case WL_STOPPED: return "WL_STOPPED";
#endif
  }

  return "UNKNOWN";
}

///////////////////////////////////////////////////////////////////////////
//  get WiFi MAC address                                                 //
///////////////////////////////////////////////////////////////////////////
byte* getHardwareAddress(void) {
  // get mac address
  byte* mac = (byte *)malloc(6 * sizeof(byte));
#if defined(ARDUINO_ARCH_ESP8266)
  WiFi.macAddress(mac);
#elif defined(ARDUINO_ARCH_ESP32)
  esp_read_mac(mac, ESP_MAC_WIFI_STA);
#endif
  return mac;
}

///////////////////////////////////////////////////////////////////////////
//  convert MAC address to string                                        //
///////////////////////////////////////////////////////////////////////////
char* getHardwareAddress(char colon) {
  byte* mac = getHardwareAddress();
  char* buff = (char *)malloc(18 * sizeof(char));
  sprintf(buff, "%02x%c%02x%c%02x%c%02x%c%02x%c%02x", 
    mac[0], 
    colon,
    mac[1],
    colon,
    mac[2],
    colon, 
    mac[3],
    colon, 
    mac[4],
    colon, 
    mac[5]
  );
  
  free(mac);
  return buff;
}

///////////////////////////////////////////////////////////////////////////
//  get WiFi soft AP                                                     //
///////////////////////////////////////////////////////////////////////////
String generateTemporarySSID(void) {
  byte* mac = getHardwareAddress();
  String ssid = String(
    mac[0] ^ mac[1] ^ mac[2] ^ mac[3] ^ mac[4] ^ mac[5], DEC
  );
  free(mac);
  return ssid;
}

///////////////////////////////////////////////////////////////////////////
//  serve WiFi AP                                                        //
///////////////////////////////////////////////////////////////////////////
void serverWifiTickCallback(void) {
  if(rebootPending || otaInProgress) {
    return;
  }

  // when a certain number of ticks have elapsed boot again to client mode
  // in order to retry the existing credentials in case the AP recovered
  unsigned long callbackTickTime = serverWifiTick.counter() * (serverWifiTick.interval() / 1000);
  if(callbackTickTime >= WIFI_SERVER_TIMEOUT) {
#ifdef DEBUG
    Serial.println("Server timeout, rebooting...\n");
#endif

    // retrieve the configuration so we do not end up overwriting the old client settings
    JsonDocument configuration;
    if(getConfiguration(CONFIGURATION_FILE_NAME, configuration) == -1) {
       // if the configuration could not be retrieved then just reboot
#ifdef DEBUG
        Serial.println("Unable to retrieve configuration.");
#endif
        rebootPending = true;
        return;
    }

    // reboot to client mode in order to retry the connection
    configuration["boot"] = BOOT_MODE_CLIENT;
    if(!setConfiguration(CONFIGURATION_FILE_NAME, configuration)) {
#ifdef DEBUG
      Serial.printf("Failed to write configuration.\n");
#endif
    }
    
    rebootPending = true;
    return;
  }

#ifdef DEBUG
/*
  if(callbackTickTime % 1000 == 0 ) {
    Serial.printf("Time till reboot %.0fs\n", (float)(WIFI_SERVER_TIMEOUT - callbackTickTime)/1000.0);
  }
*/
#endif
  
  // create the temporary SSID for the initial configuration
  String temporarySSID = generateTemporarySSID();
  if(WiFi.softAPSSID().equals(temporarySSID)) {
    // run WiFi server loops
    dnsServer.processNextRequest();
    server.handleClient();
#if defined(ESP8266)
    MDNS.update();
#endif

    if(blinkDigitsDahTick.state() == STOPPED) {
      temporarySSIDLength = temporarySSID.length();
      temporarySSIDNumbers = (int *) malloc(temporarySSIDLength * sizeof(int));
      for(int i = 0; i < temporarySSIDLength; ++i) {
        temporarySSIDNumbers[i] = temporarySSID[i] - '0';
      }
      temporarySSIDIndex = 0;
      blinkDigitsDahTick.start();
    }
    return;
  }

#ifdef DEBUG
  Serial.println("Starting HTTP server for Wifi server.");
#endif

  // handle HTTP REST requests
  server.on("/", handleRootHttpRequest);
  server.on("/setup", handleSetupHttpRequest);
  server.on("/style.css", handleRootCssRequest);
  // captive portal proprietary junk redirected to webserver root
  // connectivitycheck.gstatic.com/generate_204
  // www.googe.com/gen_204
  server.on("/generate_204", handleRootHttpRequest);
  server.on("/gen_204", handleRootHttpRequest);
  server.on("/fwlink", handleRootHttpRequest);
  server.onNotFound(handleHttpNotFound);

#ifdef DEBUG
  Serial.println("Ensure HTTP headers are collected by the HTTP server.");
#endif
#if defined(ARDUINO_ARCH_ESP8266)
  server.collectHeaders("Cookie");
#elif defined(ARDUINO_ARCH_ESP32)
  const char* collectHeaders[] = { "Cookie" };
  size_t headerkeyssize = sizeof(collectHeaders) / sizeof(char *);
  server.collectHeaders(collectHeaders, headerkeyssize);
#endif

  // the soft AP (or WiFi) must be started before the HTTP server or it will result in a crash on ESP32
#ifdef DEBUG
  Serial.println("Starting temporary AP.");
#endif

  JsonDocument configuration;
  if(getConfiguration(CONFIGURATION_FILE_NAME, configuration) == -1) {
#ifdef DEBUG
    Serial.println("Unable to retrieve configuration.");
#endif
  }

  WiFi.softAPConfig(softAPAddress, softAPAddress, softAPNetmask);
  WiFi.softAP(temporarySSID, String(), 1, false, 1);
  dnsServer.setErrorReplyCode(DNSReplyCode::NoError);
  dnsServer.start(53, "*", softAPAddress);
  
#ifdef DEBUG
  Serial.println("Starting HTTP server.");
#endif

  if (!discoveryStarted) {
    if(!MDNS.begin(temporarySSID)) {
#ifdef DEBUG
      Serial.println("Error setting up MDNS responder.");
#endif
      return;
    }
    discoveryStarted = true;
  }
  
  server.begin();
}

///////////////////////////////////////////////////////////////////////////
//  connect to WiFi                                                      //
///////////////////////////////////////////////////////////////////////////
#ifdef ESP32
void clientWifiDisconnectCallback(WiFiEvent_t event, arduino_event_info_t info) {
  if (event != ARDUINO_EVENT_WIFI_STA_DISCONNECTED) return;
  uint8_t reason = info.wifi_sta_disconnected.reason;
#elif defined(ESP8266)
void clientWifiDisconnectCallback(const WiFiEventStationModeDisconnected& event) {
  uint8_t reason = (uint8_t)event.reason;
#endif

#ifdef DEBUG
  Serial.printf("\n[WiFi] Disconnected. Reason: %u\n", reason);
#endif

  switch (reason) {
    // ESP32: 202 (AUTH_FAIL), 23 (WPA2/3 mismatch)
    // ESP8266: 15 (Handshake Timeout/Wrong Pass), 204 (Auth Fail)
    case 15:
    case 23:
    case 202:
    case 204:
    {
#ifdef DEBUG 
      Serial.println("Authentication failure or mismatch. Rebooting to server mode.");
#endif
      JsonDocument configuration;
      if(getConfiguration(CONFIGURATION_FILE_NAME, configuration) != -1) {
        configuration["boot"] = BOOT_MODE_SERVER;
        if(!setConfiguration(CONFIGURATION_FILE_NAME, configuration)) {
#ifdef DEBUG
          Serial.println("Failed to write configuration.");
#endif
        }
        rebootPending = true;
      }
      break;
    }
    default:
#ifdef DEBUG 
      Serial.println("Connection lost. Standard retry.");
#endif
      break;
  }
}

void clientWifiTickCallback(void) {
  if(rebootPending || otaInProgress) {
    return;
  }
  
  unsigned long callbackCount = clientWifiTick.counter();
#ifdef DEBUG
  //Serial.printf("Client tick %lu\n", callbackCount);
#endif
  if(callbackCount == 1) {
#ifdef DEBUG
    Serial.printf("Rescheduling client WiFi...\n");
#endif
    clientWifiTick.interval(WIFI_RETRY_TIMEOUT);
    clientWifiTick.resume();
    return;
  }
  
  // if WiFi is already connected or a reboot is pending just bail out
  wl_status_t wifiStatus = WiFi.status();
  if(wifiStatus == WL_CONNECTED) {
    if (!discoveryStarted) {
      JsonDocument configuration;
      if(getConfiguration(CONFIGURATION_FILE_NAME, configuration) == -1) {
#ifdef DEBUG
        Serial.println("Unable to retrieve configuration.");
#endif
        rebootPending = true;
        return;
      }
      
      if(!MDNS.begin(configuration["name"].as<String>())) {
#ifdef DEBUG
        Serial.println("Error setting up MDNS responder.");
#endif
        return;
      }
      discoveryStarted = true;
    }
#ifdef DEBUG
    Serial.println("-- MARK --");
#endif
    clientConnectionTries = 0;
    networkConnected = true;
#if defined(ESP8266)
    MDNS.update();
#endif
    return;
  }

#ifdef DEBUG
  Serial.printf("Client WiFi not connected: %s\n", wl_status_to_string(wifiStatus));
#endif

  networkConnected = false;

  JsonDocument configuration;
  if(getConfiguration(CONFIGURATION_FILE_NAME, configuration) == -1) {
#ifdef DEBUG
    Serial.println("Unable to retrieve configuration.");
#endif
    return;
  }

  // even if configuration exists, check whether STA and password exist
  if(!configuration["ssid"] || configuration["ssid"].as<String>().length() == 0 || 
     !configuration["password"] || configuration["password"].as<String>().length() == 0) {
    // reboot to client mode in order to retry the connection
    configuration["boot"] = BOOT_MODE_SERVER;
    if(!setConfiguration(CONFIGURATION_FILE_NAME, configuration)) {
#ifdef DEBUG
      Serial.printf("Failed to write configuration.\n");
#endif
    }
    
    rebootPending = true;
    return;
  }

  // set SSID and password
  String ssid = configuration["ssid"].as<String>();
  String password = configuration["password"].as<String>();
  
  // too many retries so reboot to soft AP
  if(++clientConnectionTries > WIFI_CONNECT_TRIES) {
    configuration["boot"] = BOOT_MODE_SERVER;
    if(!setConfiguration(CONFIGURATION_FILE_NAME, configuration)) {
#ifdef DEBUG
      Serial.printf("Failed to write configuration.\n");
#endif
    }
    
#ifdef DEBUG
    Serial.printf("Restarting in 1 second...\n");
#endif

    rebootPending = true;
    return;
  }

#ifdef DEBUG
  Serial.printf("Attempting to establish WiFi STA connecton [%d/%d]\n", (WIFI_CONNECT_TRIES - clientConnectionTries) + 1, WIFI_CONNECT_TRIES);
#endif

#if defined(ARDUINO_ARCH_ESP8266)
  WiFi.hostname(configuration["name"].as<String>());
#elif defined(ARDUINO_ARCH_ESP32)
  WiFi.setHostname(configuration["name"].as<const char*>());
#endif
  
#ifdef DEBUG
  Serial.printf("Trying connection to %s with %s...\n", ssid, password);
#endif
  //WiFi.config(INADDR_NONE, INADDR_NONE, INADDR_NONE);
  WiFi.begin(ssid, password);
}

///////////////////////////////////////////////////////////////////////////
//  blink the temporary ssid                                             //
///////////////////////////////////////////////////////////////////////////
void blinkDigitsDahTickCallback(void) {
  // wait for the dits to complete
  if(blinkDigitsDitTick.state() != STOPPED) {
    return;
  }
  
  if(temporarySSIDIndex >= temporarySSIDLength) {
    blinkDigitsDahTick.stop();
    blinkDigitsDitTick.stop();
    blinkDigitsBlinkTick.stop();
    free(temporarySSIDNumbers);
#ifdef DEBUG
    Serial.println();
    Serial.println("Dah-dit blink sequence completed.");
#endif
    return;
  }
  
#ifdef DEBUG
  Serial.printf("Starting to blink %d times: ", temporarySSIDNumbers[temporarySSIDIndex]);
#endif

  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, LOW); 
  blinkDigitsDitTick.start();
}

void blinkDigitsDitTickCallback(void) {
#ifdef DEBUG
  Serial.printf("Dit: %d/%d\n", blinkDigitsDitTick.counter(), temporarySSIDNumbers[temporarySSIDIndex]);
#endif
  if(blinkDigitsDitTick.counter() > temporarySSIDNumbers[temporarySSIDIndex]) {
    blinkDigitsDitTick.stop();
    ++temporarySSIDIndex;
#ifdef DEBUG
    Serial.println("Dits completed...");
#endif
    return;
  }
  
  blinkDigitsDitTick.pause();
  blinkDigitsBlinkTick.start();
}

void blinkDigitsBlinkTickCallback(void) {
  if(blinkDigitsBlinkTick.counter() > 2) {
    blinkDigitsBlinkTick.stop();    
    blinkDigitsDitTick.resume();
    return;
  }
  blinkLedState = !blinkLedState;
  digitalWrite(LED_BUILTIN, blinkLedState);
}